[27222] in Source-Commits
/svn/athena r26029 - in trunk/debathena/debathena/aclocal: aclocal debian
daemon@ATHENA.MIT.EDU (Alexander Chernyakhovsky)
Sun Jun 2 00:23:46 2013
Date: Sun, 2 Jun 2013 00:23:38 -0400
From: Alexander Chernyakhovsky <achernya@MIT.EDU>
Message-Id: <201306020423.r524NcwI004351@drugstore.mit.edu>
To: source-commits@MIT.EDU
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit
Author: achernya
Date: 2013-06-02 00:23:37 -0400 (Sun, 02 Jun 2013)
New Revision: 26029
Added:
trunk/debathena/debathena/aclocal/aclocal/kafs.m4
trunk/debathena/debathena/aclocal/aclocal/krb5-config.m4
trunk/debathena/debathena/aclocal/aclocal/krb5.m4
trunk/debathena/debathena/aclocal/aclocal/lib-depends.m4
trunk/debathena/debathena/aclocal/aclocal/lib-pathname.m4
Modified:
trunk/debathena/debathena/aclocal/debian/changelog
trunk/debathena/debathena/aclocal/debian/control
trunk/debathena/debathena/aclocal/debian/debathena-aclocal.install
trunk/debathena/debathena/aclocal/debian/rules
Log:
In aclocal:
* Convert to dh7
* Include Russ Allbery's excellent AFS and KRB5 detection macros in
preparation to transition away from the old-style Athena macros.
Added: trunk/debathena/debathena/aclocal/aclocal/kafs.m4
===================================================================
--- trunk/debathena/debathena/aclocal/aclocal/kafs.m4 (rev 0)
+++ trunk/debathena/debathena/aclocal/aclocal/kafs.m4 2013-06-02 04:23:37 UTC (rev 26029)
@@ -0,0 +1,243 @@
+dnl Test for a libkafs library or replacement.
+dnl
+dnl Check for a working libkafs library, and if not present, check how we can
+dnl simulate what one would do ourselves, adding the appropriate things to
+dnl LIBOBJS. Provides the --with-libkafs configure option specify a
+dnl non-standard path to libkafs or (as --without-libkafs) to force use of the
+dnl internal implementation; --with-libkafs-include and --with-libkafs-lib to
+dnl specify paths at a more granular level; and --with-afs,
+dnl --with-afs-include, and --with-afs-lib configure options to specify the
+dnl location of the AFS libraries.
+dnl
+dnl Provides the macro RRA_LIB_KAFS and sets the substition variables
+dnl KAFS_CPPFLAGS, KAFS_LDFLAGS, and KAFS_LIBS. If Kerberos libraries may be
+dnl needed, LIBS and LDFLAGS must already be set appropriately before calling
+dnl this. Also provides RRA_LIB_KAFS_SWITCH to set CPPFLAGS, LDFLAGS, and
+dnl LIBS to include libkafs, saving the current values first, and
+dnl RRA_LIB_KAFS_RESTORE to restore those settings to before the last
+dnl RRA_LIB_KFS_SWITCH.
+dnl
+dnl Sets HAVE_K_HASAFS if the k_hasafs function was found in a libkafs
+dnl library. Sets HAVE_LSETPAG if building against the AFS libraries and the
+dnl lsetpag function is present. Sets HAVE_KAFS_REPLACEMENT if building the
+dnl replacement kafs library. Defines HAVE_KAFS_DARWIN8, HAVE_KAFS_DARWIN10,
+dnl HAVE_KAFS_LINUX, HAVE_KAFS_SOLARIS, or HAVE_KAFS_SYSCALL as appropriate if
+dnl the replacement kafs library is needed.
+dnl
+dnl If building a replacement library is needed, sets rra_build_kafs to true.
+dnl Otherwise, sets it to false. This is intended for use with an Automake
+dnl conditional, but the Automake conditional isn't set directly by this macro
+dnl since AFS support may be optional in the larger package.
+dnl
+dnl Depends on RRA_SET_LDFLAGS.
+dnl
+dnl The canonical version of this file is maintained in the rra-c-util
+dnl package, available at <http://www.eyrie.org/~eagle/software/rra-c-util/>.
+dnl
+dnl Written by Russ Allbery <rra@stanford.edu>
+dnl Copyright 2008, 2009, 2010
+dnl The Board of Trustees of the Leland Stanford Junior University
+dnl
+dnl This file is free software; the authors give unlimited permission to copy
+dnl and/or distribute it, with or without modifications, as long as this
+dnl notice is preserved.
+
+dnl Save the current CPPFLAGS, LDFLAGS, and LIBS settings and switch to
+dnl versions that include the libkafs flags. Used as a wrapper, with
+dnl RRA_LIB_KAFS_RESTORE, around tests.
+AC_DEFUN([RRA_LIB_KAFS_SWITCH],
+[rra_kafs_save_CPPFLAGS="$CPPFLAGS"
+ rra_kafs_save_LDFLAGS="$LDFLAGS"
+ rra_kafs_save_LIBS="$LIBS"
+ CPPFLAGS="$KAFS_CPPFLAGS $CPPFLAGS"
+ LDFLAGS="$KAFS_LDFLAGS $LDFLAGS"
+ LIBS="$KAFS_LIBS $LIBS"])
+
+dnl Restore CPPFLAGS, LDFLAGS, and LIBS to their previous values (before
+dnl RRA_LIB_KAFS_SWITCH was called).
+AC_DEFUN([RRA_LIB_KAFS_RESTORE],
+[CPPFLAGS="$rra_kafs_save_CPPFLAGS"
+ LDFLAGS="$rra_kafs_save_LDFLAGS"
+ LIBS="$rra_kafs_save_LIBS"])
+
+dnl Set KAFS_CPPFLAGS and KAFS_LDFLAGS based on rra_kafs_root,
+dnl rra_kafs_libdir, rra_kafs_includedir, rra_afs_root, rra_afs_libdir, and
+dnl rra_afs_includedir.
+AC_DEFUN([_RRA_LIB_KAFS_PATHS],
+[KAFS_LDFLAGS=
+ AS_IF([test x"$rra_kafs_libdir" != x],
+ [KAFS_LDFLAGS="-L$rra_kafs_libdir"],
+ [AS_IF([test x"$rra_kafs_root" != x],
+ [RRA_SET_LDFLAGS([KAFS_LDFLAGS], [$rra_kafs_root])])])
+ AS_IF([test x"$rra_kafs_includedir" != x],
+ [KAFS_CPPFLAGS="-I$rra_kafs_includedir"],
+ [AS_IF([test x"$rra_kafs_root" != x],
+ [AS_IF([test x"$rra_kafs_root" != x/usr],
+ [KAFS_CPPFLAGS="-I${rra_kafs_root}/include"])])])
+ AS_IF([test x"$rra_afs_libdir" != x],
+ [KAFS_LDFLAGS="$KAFS_LDFLAGS -L$rra_afs_libdir"],
+ [AS_IF([test x"$rra_afs_root" != x],
+ [RRA_SET_LDFLAGS([KAFS_LDFLAGS], [$rra_afs_root])])
+ RRA_SET_LDFLAGS([KAFS_LDFLAGS], [$rra_afs_root], [afs])])
+ AS_IF([test x"$rra_afs_includedir" != x],
+ [KAFS_CPPFLAGS="-I$rra_afs_includedir"],
+ [AS_IF([test x"$rra_afs_root" != x],
+ [AS_IF([test x"$rra_afs_root" != x/usr],
+ [KAFS_CPPFLAGS="$KAFS_CPPFLAGS -I${rra_afs_root}/include"])])])])
+
+dnl Probe for lsetpag in the AFS libraries. This is required on AIX and IRIX
+dnl since we can't use the regular syscall interface there.
+AC_DEFUN([_RRA_LIB_KAFS_LSETPAG],
+[RRA_LIB_KAFS_SWITCH
+ LIBS=
+ AC_SEARCH_LIBS([pthread_getspecific], [pthread])
+ AC_SEARCH_LIBS([res_search], [resolv], [],
+ [AC_SEARCH_LIBS([__res_search], [resolv])])
+ AC_SEARCH_LIBS([gethostbyname], [nsl])
+ AC_SEARCH_LIBS([socket], [socket], [],
+ [AC_CHECK_LIB([nsl], [socket], [LIBS="-lnsl -lsocket $LIBS"], [],
+ [-lsocket])])
+ rra_kafs_extra="$LIBS"
+ LIBS="$rra_kafs_save_LIBS"
+ AC_CHECK_LIB([afsauthent], [lsetpag],
+ [KAFS_LIBS="-lafsauthent -lafsrpc $rra_kafs_extra"
+ AC_DEFINE([HAVE_LSETPAG], [1],
+ [Define to 1 if you have the OpenAFS lsetpag function.])],
+ [AC_CHECK_LIB([sys], [lsetpag],
+ [KAFS_LIBS="-lsys $rra_kafs_extra"
+ AC_DEFINE([HAVE_LSETPAG], [1],
+ [Define to 1 if you have the OpenAFS lsetpag function.])], [],
+ [$rra_kafs_extra])],
+ [-lafsrpc $rra_kafs_extra])
+ AC_CHECK_HEADERS([afs/afssyscalls.h])
+ RRA_LIB_KAFS_RESTORE])
+
+dnl The public entry point. Sets up the --with options and then decides what
+dnl to do based on the system. Either RRA_LIB_KRB5 or RRA_LIB_KRB5_OPTIONAL
+dnl must be called before this function or the Heimdal libkafs may not be
+dnl available.
+AC_DEFUN([RRA_LIB_KAFS],
+[AC_REQUIRE([AC_CANONICAL_HOST])
+ rra_libkafs=true
+ rra_build_kafs=false
+ KAFS_CPPFLAGS=
+ KAFS_LDFLAGS=
+ KAFS_LIBS=
+ AC_SUBST([KAFS_CPPFLAGS])
+ AC_SUBST([KAFS_LDFLAGS])
+ AC_SUBST([KAFS_LIBS])
+
+ dnl In addition to the normal path-finding options, support --without-libkafs
+ dnl to force always using the internal AFS syscall code.
+ AC_ARG_WITH([libkafs],
+ AC_HELP_STRING([--with-libkafs=DIR],
+ [Location of kafs headers and libraries]),
+ [AS_IF([test x"$withval" = xno],
+ [rra_libkafs=false],
+ [AS_IF([test x"$withval" != xyes], [rra_krb5_root="$withval"])])])
+ AC_ARG_WITH([libkafs-include],
+ [AS_HELP_STRING([--with-libkafs-include=DIR],
+ [Location of kafs headers])],
+ [AS_IF([test x"$withval" != xyes && test x"$withval" != xno],
+ [rra_kafs_includedir="$withval"])])
+ AC_ARG_WITH([libkafs-lib],
+ [AS_HELP_STRING([--with-libkafs-lib=DIR],
+ [Location of kafs libraries])],
+ [AS_IF([test x"$withval" != xyes && test x"$withval" != xno],
+ [rra_kafs_libdir="$withval"])])
+
+ dnl The location of the AFS headers and libraries. We may not use these
+ dnl results, but configure always includes the prompt, so always handle them.
+ dnl This should probably be in a separate macro file.
+ AC_ARG_WITH([afs],
+ [AC_HELP_STRING([--with-afs=DIR],
+ [Location of AFS headers and libraries])],
+ [AS_IF([test x"$withval" != xno && test x"$withval" != xyes],
+ [rra_afs_root="$withval"])])
+ AC_ARG_WITH([afs-include],
+ [AS_HELP_STRING([--with-afs-include=DIR],
+ [Location of AFS headers])],
+ [AS_IF([test x"$withval" != xyes && test x"$withval" != xno],
+ [rra_afs_includedir="$withval"])])
+ AC_ARG_WITH([afs-lib],
+ [AS_HELP_STRING([--with-afs-lib=DIR],
+ [Location of AFS libraries])],
+ [AS_IF([test x"$withval" != xyes && test x"$withval" != xno],
+ [rra_afs_libdir="$withval"])])
+
+ dnl If we may use the system libkafs, see if we can find one. Enable the
+ dnl Kerberos libraries if we found any, in case libkafs depends on Kerberos.
+ AC_CHECK_HEADERS([sys/ioccom.h])
+ AS_IF([test x"$rra_libkafs" != xfalse],
+ [_RRA_LIB_KAFS_PATHS
+ AS_IF([test x"$rra_use_kerberos" = xtrue],
+ [RRA_LIB_KRB5_SWITCH])
+ RRA_LIB_KAFS_SWITCH
+ AC_CHECK_LIB([kafs], [k_hasafs],
+ [KAFS_LIBS="-lkafs"
+ AC_CHECK_HEADERS([kafs.h])],
+ [AC_CHECK_LIB([kopenafs], [k_hasafs],
+ [KAFS_LIBS="-lkopenafs"
+ AC_CHECK_HEADERS([kopenafs.h])],
+ [rra_libkafs=false])])
+ RRA_LIB_KAFS_RESTORE
+ RRA_LIB_KAFS_SWITCH
+ AC_CHECK_FUNCS([k_pioctl])
+ AC_REPLACE_FUNCS([k_haspag])
+ RRA_LIB_KAFS_RESTORE
+ AS_IF([test x"$rra_use_kerberos" = xtrue],
+ [RRA_LIB_KRB5_RESTORE])])
+
+ dnl If we found a libkafs, we have k_hasafs. Set the appropriate
+ dnl preprocessor define. Otherwise, we'll use our portability layer.
+ AS_IF([test x"$rra_libkafs" = xtrue],
+ [AC_DEFINE([HAVE_K_HASAFS], 1,
+ [Define to 1 if you have the k_hasafs function.])],
+ [AC_LIBOBJ([k_haspag])
+ AS_CASE([$host],
+ [[*-apple-darwin[89]*]],
+ [rra_build_kafs=true
+ AC_DEFINE([HAVE_KAFS_REPLACEMENT], [1],
+ [Define to 1 if the libkafs replacement is built.])
+ AC_DEFINE([HAVE_KAFS_DARWIN8], [1],
+ [Define to 1 to use the Mac OS X 10.4 /dev interface.])],
+
+ [*-apple-darwin1*],
+ [rra_build_kafs=true
+ AC_DEFINE([HAVE_KAFS_REPLACEMENT], [1],
+ [Define to 1 if the libkafs replacement is built.])
+ AC_DEFINE([HAVE_KAFS_DARWIN10], [1],
+ [Define to 1 to use the Mac OS X 10.6 /dev interface.])],
+
+ [*-aix*|*-irix*],
+ [_RRA_LIB_KAFS_LSETPAG],
+
+ [*-linux*],
+ [rra_build_kafs=true
+ AC_DEFINE([HAVE_KAFS_REPLACEMENT], [1],
+ [Define to 1 if the libkafs replacement is built.])
+ AC_DEFINE([HAVE_KAFS_LINUX], [1],
+ [Define to 1 to use the Linux AFS /proc interface.])],
+
+ [[*-solaris2.1[12345678]*]],
+ [rra_build_kafs=true
+ AC_DEFINE([HAVE_KAFS_REPLACEMENT], [1],
+ [Define to 1 if the libkafs replacement is built.])
+ AC_DEFINE([HAVE_KAFS_SOLARIS], [1],
+ [Define to 1 to use the Solaris 11 /dev interface.])
+ AC_DEFINE([_REENTRANT], [1],
+ [Define to 1 on Solaris for threaded errno handling.])],
+
+ [*],
+ [rra_build_kafs=true
+ _RRA_LIB_KAFS_PATHS
+ RRA_LIB_KAFS_SWITCH
+ AC_CHECK_HEADERS([afs/param.h], [],
+ [AC_MSG_ERROR([need afs/param.h to build libkafs replacement])])
+ RRA_LIB_KAFS_RESTORE
+ AC_DEFINE([HAVE_KAFS_REPLACEMENT], [1],
+ [Define to 1 if the libkafs replacement is built.])
+ AC_DEFINE([HAVE_KAFS_SYSCALL], [1],
+ [Define to 1 to use the AFS syscall interface.])
+ AC_DEFINE([_REENTRANT], [1],
+ [Define to 1 on Solaris for threaded errno handling.])])])])
Added: trunk/debathena/debathena/aclocal/aclocal/krb5-config.m4
===================================================================
--- trunk/debathena/debathena/aclocal/aclocal/krb5-config.m4 (rev 0)
+++ trunk/debathena/debathena/aclocal/aclocal/krb5-config.m4 2013-06-02 04:23:37 UTC (rev 26029)
@@ -0,0 +1,101 @@
+dnl Use krb5-config to get link paths for Kerberos libraries.
+dnl
+dnl Provides one macro, RRA_KRB5_CONFIG, which attempts to get compiler and
+dnl linker flags for a library via krb5-config and sets the appropriate shell
+dnl variables. Defines the Autoconf variable PATH_KRB5_CONFIG, which can be
+dnl used to find the default path to krb5-config.
+dnl
+dnl Depends on RRA_ENABLE_REDUCED_DEPENDS.
+dnl
+dnl The canonical version of this file is maintained in the rra-c-util
+dnl package, available at <http://www.eyrie.org/~eagle/software/rra-c-util/>.
+dnl
+dnl Written by Russ Allbery <rra@stanford.edu>
+dnl Copyright 2011, 2012
+dnl The Board of Trustees of the Leland Stanford Junior University
+dnl
+dnl This file is free software; the authors give unlimited permission to copy
+dnl and/or distribute it, with or without modifications, as long as this
+dnl notice is preserved.
+
+dnl Check for krb5-config in the user's path and set PATH_KRB5_CONFIG. This
+dnl is moved into a separate macro so that it can be loaded via AC_REQUIRE,
+dnl meaning it will only be run once even if we link with multiple krb5-config
+dnl libraries.
+AC_DEFUN([_RRA_KRB5_CONFIG_PATH],
+[AC_ARG_VAR([PATH_KRB5_CONFIG], [Path to krb5-config])
+ AC_PATH_PROG([PATH_KRB5_CONFIG], [krb5-config], [],
+ [${PATH}:/usr/kerberos/bin])])
+
+dnl Check whether the --deps flag is supported by krb5-config. Takes the path
+dnl to krb5-config to use. Note that this path is not embedded in the cache
+dnl variable, so this macro implicitly assumes that we will always use the
+dnl same krb5-config program.
+AC_DEFUN([_RRA_KRB5_CONFIG_DEPS],
+[AC_REQUIRE([_RRA_KRB5_CONFIG_PATH])
+ AC_CACHE_CHECK([for --deps support in krb5-config],
+ [rra_cv_krb5_config_deps],
+ [AS_IF(["$1" 2>&1 | grep deps >/dev/null 2>&1],
+ [rra_cv_krb5_config_deps=yes],
+ [rra_cv_krb5_config_deps=no])])])
+
+dnl Obtain the library flags for a particular library using krb5-config.
+dnl Takes the path to the krb5-config program to use, the argument to
+dnl krb5-config to use, and the variable prefix under which to store the
+dnl library flags.
+AC_DEFUN([_RRA_KRB5_CONFIG_LIBS],
+[AC_REQUIRE([_RRA_KRB5_CONFIG_PATH])
+ AC_REQUIRE([RRA_ENABLE_REDUCED_DEPENDS])
+ _RRA_KRB5_CONFIG_DEPS([$1])
+ AS_IF([test x"$rra_reduced_depends" = xfalse \
+ && test x"$rra_cv_krb5_config_deps" = xyes],
+ [$3[]_LIBS=`"$1" --deps --libs $2 2>/dev/null`],
+ [$3[]_LIBS=`"$1" --libs $2 2>/dev/null`])])
+
+dnl Attempt to find the flags for a library using krb5-config. Takes the
+dnl following arguments (in order):
+dnl
+dnl 1. The root directory for the library in question, generally from an
+dnl Autoconf --with flag. Used by preference as the path to krb5-config.
+dnl
+dnl 2. The argument to krb5-config to retrieve flags for this particular
+dnl library.
+dnl
+dnl 3. The variable prefix to use when setting CPPFLAGS and LIBS variables
+dnl based on the result of krb5-config.
+dnl
+dnl 4. Further actions to take if krb5-config was found and supported that
+dnl library type.
+dnl
+dnl 5. Further actions to take if krb5-config could not be used to get flags
+dnl for that library type.
+dnl
+dnl Special-case a krb5-config argument of krb5 and run krb5-config without an
+dnl argument if that option was requested and not supported. Old versions of
+dnl krb5-config didn't take an argument to specify the library type, but
+dnl always returned the flags for libkrb5.
+AC_DEFUN([RRA_KRB5_CONFIG],
+[AC_REQUIRE([_RRA_KRB5_CONFIG_PATH])
+ rra_krb5_config_$3=
+ rra_krb5_config_$3[]_ok=
+ AS_IF([test x"$1" != x && test -x "$1/bin/krb5-config"],
+ [rra_krb5_config_$3="$1/bin/krb5-config"],
+ [rra_krb5_config_$3="$PATH_KRB5_CONFIG"])
+ AS_IF([test x"$rra_krb5_config_$3" != x && test -x "$rra_krb5_config_$3"],
+ [AC_CACHE_CHECK([for $2 support in krb5-config], [rra_cv_lib_$3[]_config],
+ [AS_IF(["$rra_krb5_config_$3" 2>&1 | grep $2 >/dev/null 2>&1],
+ [rra_cv_lib_$3[]_config=yes],
+ [rra_cv_lib_$3[]_config=no])])
+ AS_IF([test "$rra_cv_lib_$3[]_config" = yes],
+ [$3[]_CPPFLAGS=`"$rra_krb5_config_$3" --cflags $2 2>/dev/null`
+ _RRA_KRB5_CONFIG_LIBS([$rra_krb5_config_$3], [$2], [$3])
+ rra_krb5_config_$3[]_ok=yes],
+ [AS_IF([test x"$2" = xkrb5],
+ [$3[]_CPPFLAGS=`"$rra_krb5_config_$3" --cflags 2>/dev/null`
+ $3[]_LIBS=`"$rra_krb5_config_$3" --libs $2 2>/dev/null`
+ rra_krb5_config_$3[]_ok=yes])])])
+ AS_IF([test x"$rra_krb5_config_$3[]_ok" = xyes],
+ [$3[]_CPPFLAGS=`echo "$$3[]_CPPFLAGS" | sed 's%-I/usr/include %%'`
+ $3[]_CPPFLAGS=`echo "$$3[]_CPPFLAGS" | sed 's%-I/usr/include$%%'`
+ $4],
+ [$5])])
Added: trunk/debathena/debathena/aclocal/aclocal/krb5.m4
===================================================================
--- trunk/debathena/debathena/aclocal/aclocal/krb5.m4 (rev 0)
+++ trunk/debathena/debathena/aclocal/aclocal/krb5.m4 2013-06-02 04:23:37 UTC (rev 26029)
@@ -0,0 +1,336 @@
+dnl Find the compiler and linker flags for Kerberos.
+dnl
+dnl Finds the compiler and linker flags for linking with Kerberos libraries.
+dnl Provides the --with-krb5, --with-krb5-include, and --with-krb5-lib
+dnl configure options to specify non-standard paths to the Kerberos libraries.
+dnl Uses krb5-config where available unless reduced dependencies is requested
+dnl or --with-krb5-include or --with-krb5-lib are given.
+dnl
+dnl Provides the macro RRA_LIB_KRB5 and sets the substitution variables
+dnl KRB5_CPPFLAGS, KRB5_LDFLAGS, and KRB5_LIBS. Also provides
+dnl RRA_LIB_KRB5_SWITCH to set CPPFLAGS, LDFLAGS, and LIBS to include the
+dnl Kerberos libraries, saving the current values first, and
+dnl RRA_LIB_KRB5_RESTORE to restore those settings to before the last
+dnl RRA_LIB_KRB5_SWITCH. HAVE_KERBEROS will always be defined if RRA_LIB_KRB5
+dnl is used.
+dnl
+dnl If KRB5_CPPFLAGS, KRB5_LDFLAGS, or KRB5_LIBS are set before calling these
+dnl macros, their values will be added to whatever the macros discover.
+dnl
+dnl Provides the RRA_LIB_KRB5_OPTIONAL macro, which should be used if Kerberos
+dnl support is optional. This macro will still always set the substitution
+dnl variables, but they'll be empty unless --with-krb5 is given. Also,
+dnl HAVE_KERBEROS will be defined if --with-krb5 is given and
+dnl $rra_use_kerberos will be set to "true".
+dnl
+dnl Sets the Automake conditional KRB5_USES_COM_ERR saying whether we use
+dnl com_err, since if we're also linking with AFS libraries, we may have to
+dnl change library ordering in that case.
+dnl
+dnl Depends on RRA_ENABLE_REDUCED_DEPENDS and RRA_SET_LDFLAGS.
+dnl
+dnl Also provides RRA_FUNC_KRB5_GET_INIT_CREDS_OPT_FREE_ARGS, which checks
+dnl whether krb5_get_init_creds_opt_free takes one argument or two. Defines
+dnl HAVE_KRB5_GET_INIT_CREDS_OPT_FREE_2_ARGS if it takes two arguments.
+dnl
+dnl Also provides RRA_INCLUDES_KRB5, which are the headers to include when
+dnl probing the Kerberos library properties.
+dnl
+dnl The canonical version of this file is maintained in the rra-c-util
+dnl package, available at <http://www.eyrie.org/~eagle/software/rra-c-util/>.
+dnl
+dnl Written by Russ Allbery <rra@stanford.edu>
+dnl Copyright 2005, 2006, 2007, 2008, 2009, 2010, 2011
+dnl The Board of Trustees of the Leland Stanford Junior University
+dnl
+dnl This file is free software; the authors give unlimited permission to copy
+dnl and/or distribute it, with or without modifications, as long as this
+dnl notice is preserved.
+
+dnl Headers to include when probing for Kerberos library properties.
+AC_DEFUN([RRA_INCLUDES_KRB5], [[
+#if HAVE_KRB5_H
+# include <krb5.h>
+#else
+# include <krb5/krb5.h>
+#endif
+]])
+
+dnl Save the current CPPFLAGS, LDFLAGS, and LIBS settings and switch to
+dnl versions that include the Kerberos flags. Used as a wrapper, with
+dnl RRA_LIB_KRB5_RESTORE, around tests.
+AC_DEFUN([RRA_LIB_KRB5_SWITCH],
+[rra_krb5_save_CPPFLAGS="$CPPFLAGS"
+ rra_krb5_save_LDFLAGS="$LDFLAGS"
+ rra_krb5_save_LIBS="$LIBS"
+ CPPFLAGS="$KRB5_CPPFLAGS $CPPFLAGS"
+ LDFLAGS="$KRB5_LDFLAGS $LDFLAGS"
+ LIBS="$KRB5_LIBS $LIBS"])
+
+dnl Restore CPPFLAGS, LDFLAGS, and LIBS to their previous values (before
+dnl RRA_LIB_KRB5_SWITCH was called).
+AC_DEFUN([RRA_LIB_KRB5_RESTORE],
+[CPPFLAGS="$rra_krb5_save_CPPFLAGS"
+ LDFLAGS="$rra_krb5_save_LDFLAGS"
+ LIBS="$rra_krb5_save_LIBS"])
+
+dnl Set KRB5_CPPFLAGS and KRB5_LDFLAGS based on rra_krb5_root,
+dnl rra_krb5_libdir, and rra_krb5_includedir.
+AC_DEFUN([_RRA_LIB_KRB5_PATHS],
+[AS_IF([test x"$rra_krb5_libdir" != x],
+ [KRB5_LDFLAGS="-L$rra_krb5_libdir"],
+ [AS_IF([test x"$rra_krb5_root" != x],
+ [RRA_SET_LDFLAGS([KRB5_LDFLAGS], [$rra_krb5_root])])])
+ AS_IF([test x"$rra_krb5_includedir" != x],
+ [KRB5_CPPFLAGS="-I$rra_krb5_includedir"],
+ [AS_IF([test x"$rra_krb5_root" != x],
+ [AS_IF([test x"$rra_krb5_root" != x/usr],
+ [KRB5_CPPFLAGS="-I${rra_krb5_root}/include"])])])])
+
+dnl Check for a header using a file existence check rather than using
+dnl AC_CHECK_HEADERS. This is used if there were arguments to configure
+dnl specifying the Kerberos header path, since we may have one header in the
+dnl default include path and another under our explicitly-configured Kerberos
+dnl location.
+AC_DEFUN([_RRA_LIB_KRB5_CHECK_HEADER],
+[AC_MSG_CHECKING([for $1])
+ AS_IF([test -f "${rra_krb5_incroot}/$1"],
+ [AC_DEFINE_UNQUOTED(AS_TR_CPP([HAVE_$1]), [1],
+ [Define to 1 if you have the <$1> header file.])
+ AC_MSG_RESULT([yes])],
+ [AC_MSG_RESULT([no])])])
+
+dnl Does the appropriate library checks for reduced-dependency Kerberos
+dnl linkage. The single argument, if true, says to fail if Kerberos could not
+dnl be found.
+AC_DEFUN([_RRA_LIB_KRB5_REDUCED],
+[RRA_LIB_KRB5_SWITCH
+ AC_CHECK_LIB([krb5], [krb5_init_context], [KRB5_LIBS="-lkrb5"],
+ [AS_IF([test x"$1" = xtrue],
+ [AC_MSG_ERROR([cannot find usable Kerberos library])])])
+ LIBS="$KRB5_LIBS $LIBS"
+ AS_IF([test x"$rra_krb5_incroot" = x],
+ [AC_CHECK_HEADERS([krb5.h krb5/krb5.h])],
+ [_RRA_LIB_KRB5_CHECK_HEADER([krb5.h])
+ _RRA_LIB_KRB5_CHECK_HEADER([krb5/krb5.h])])
+ AC_CHECK_FUNCS([krb5_get_error_message],
+ [AC_CHECK_FUNCS([krb5_free_error_message])],
+ [AC_CHECK_FUNCS([krb5_get_error_string], [],
+ [AC_CHECK_FUNCS([krb5_get_err_txt], [],
+ [AC_CHECK_LIB([ksvc], [krb5_svc_get_msg],
+ [KRB5_LIBS="$KRB5_LIBS -lksvc"
+ AC_DEFINE([HAVE_KRB5_SVC_GET_MSG], [1])
+ AC_CHECK_HEADERS([ibm_svc/krb5_svc.h], [], [],
+ [RRA_INCLUDES_KRB5])],
+ [AC_CHECK_LIB([com_err], [com_err],
+ [KRB5_LIBS="$KRB5_LIBS -lcom_err"],
+ [AC_MSG_ERROR([cannot find usable com_err library])])
+ AC_CHECK_HEADERS([et/com_err.h])])])])])
+ RRA_LIB_KRB5_RESTORE])
+
+dnl Does the appropriate library checks for Kerberos linkage when we don't
+dnl have krb5-config or reduced dependencies. The single argument, if true,
+dnl says to fail if Kerberos could not be found.
+AC_DEFUN([_RRA_LIB_KRB5_MANUAL],
+[RRA_LIB_KRB5_SWITCH
+ rra_krb5_extra=
+ LIBS=
+ AC_SEARCH_LIBS([res_search], [resolv], [],
+ [AC_SEARCH_LIBS([__res_search], [resolv])])
+ AC_SEARCH_LIBS([gethostbyname], [nsl])
+ AC_SEARCH_LIBS([socket], [socket], [],
+ [AC_CHECK_LIB([nsl], [socket], [LIBS="-lnsl -lsocket $LIBS"], [],
+ [-lsocket])])
+ AC_SEARCH_LIBS([crypt], [crypt])
+ AC_SEARCH_LIBS([roken_concat], [roken])
+ rra_krb5_extra="$LIBS"
+ LIBS="$rra_krb5_save_LIBS"
+ AC_CHECK_LIB([krb5], [krb5_init_context],
+ [KRB5_LIBS="-lkrb5 -lasn1 -lcom_err -lcrypto $rra_krb5_extra"],
+ [AC_CHECK_LIB([krb5support], [krb5int_getspecific],
+ [rra_krb5_extra="-lkrb5support $rra_krb5_extra"],
+ [AC_CHECK_LIB([pthreads], [pthread_setspecific],
+ [rra_krb5_pthread="-lpthreads"],
+ [AC_CHECK_LIB([pthread], [pthread_setspecific],
+ [rra_krb5_pthread="-lpthread"])])
+ AC_CHECK_LIB([krb5support], [krb5int_setspecific],
+ [rra_krb5_extra="-lkrb5support $rra_krb5_extra $rra_krb5_pthread"],
+ [], [$rra_krb5_pthread $rra_krb5_extra])],
+ [$rra_krb5_extra])
+ AC_CHECK_LIB([com_err], [error_message],
+ [rra_krb5_extra="-lcom_err $rra_krb5_extra"], [], [$rra_krb5_extra])
+ AC_CHECK_LIB([ksvc], [krb5_svc_get_msg],
+ [rra_krb5_extra="-lksvc $rra_krb5_extra"], [], [$rra_krb5_extra])
+ AC_CHECK_LIB([k5crypto], [krb5int_hash_md5],
+ [rra_krb5_extra="-lk5crypto $rra_krb5_extra"], [], [$rra_krb5_extra])
+ AC_CHECK_LIB([k5profile], [profile_get_values],
+ [rra_krb5_extra="-lk5profile $rra_krb5_extra"], [], [$rra_krb5_extra])
+ AC_CHECK_LIB([krb5], [krb5_cc_default],
+ [KRB5_LIBS="-lkrb5 $rra_krb5_extra"],
+ [AS_IF([test x"$1" = xtrue],
+ [AC_MSG_ERROR([cannot find usable Kerberos library])])],
+ [$rra_krb5_extra])],
+ [-lasn1 -lcom_err -lcrypto $rra_krb5_extra])
+ LIBS="$KRB5_LIBS $LIBS"
+ AS_IF([test x"$rra_krb5_incroot" = x],
+ [AC_CHECK_HEADERS([krb5.h krb5/krb5.h])],
+ [_RRA_LIB_KRB5_CHECK_HEADER([krb5.h])
+ _RRA_LIB_KRB5_CHECK_HEADER([krb5/krb5.h])])
+ AC_CHECK_FUNCS([krb5_get_error_message],
+ [AC_CHECK_FUNCS([krb5_free_error_message])],
+ [AC_CHECK_FUNCS([krb5_get_error_string], [],
+ [AC_CHECK_FUNCS([krb5_get_err_txt], [],
+ [AC_CHECK_FUNCS([krb5_svc_get_msg],
+ [AC_CHECK_HEADERS([ibm_svc/krb5_svc.h], [], [],
+ [RRA_INCLUDES_KRB5])],
+ [AC_CHECK_HEADERS([et/com_err.h])])])])])
+ RRA_LIB_KRB5_RESTORE])
+
+dnl Sanity-check the results of krb5-config and be sure we can really link a
+dnl Kerberos program. If that fails, clear KRB5_CPPFLAGS and KRB5_LIBS so
+dnl that we know we don't have usable flags and fall back on the manual
+dnl check.
+AC_DEFUN([_RRA_LIB_KRB5_CHECK],
+[RRA_LIB_KRB5_SWITCH
+ AC_CHECK_FUNC([krb5_init_context],
+ [RRA_LIB_KRB5_RESTORE],
+ [RRA_LIB_KRB5_RESTORE
+ KRB5_CPPFLAGS=
+ KRB5_LIBS=
+ _RRA_LIB_KRB5_PATHS
+ _RRA_LIB_KRB5_MANUAL([$1])])])
+
+dnl Determine Kerberos compiler and linker flags from krb5-config. Does the
+dnl additional probing we need to do to uncover error handling features, and
+dnl falls back on the manual checks.
+AC_DEFUN([_RRA_LIB_KRB5_CONFIG],
+[RRA_KRB5_CONFIG([${rra_krb5_root}], [krb5], [KRB5],
+ [_RRA_LIB_KRB5_CHECK([$1])
+ RRA_LIB_KRB5_SWITCH
+ AS_IF([test x"$rra_krb5_incroot" = x],
+ [AC_CHECK_HEADERS([krb5.h krb5/krb5.h])],
+ [_RRA_LIB_KRB5_CHECK_HEADER([krb5.h])
+ _RRA_LIB_KRB5_CHECK_HEADER([krb5/krb5.h])])
+ AC_CHECK_FUNCS([krb5_get_error_message],
+ [AC_CHECK_FUNCS([krb5_free_error_message])],
+ [AC_CHECK_FUNCS([krb5_get_error_string], [],
+ [AC_CHECK_FUNCS([krb5_get_err_txt], [],
+ [AC_CHECK_FUNCS([krb5_svc_get_msg],
+ [AC_CHECK_HEADERS([ibm_svc/krb5_svc.h], [], [],
+ [RRA_INCLUDES_KRB5])],
+ [AC_CHECK_HEADERS([et/com_err.h])])])])])
+ RRA_LIB_KRB5_RESTORE],
+ [_RRA_LIB_KRB5_PATHS
+ _RRA_LIB_KRB5_MANUAL([$1])])])
+
+dnl The core of the library checking, shared between RRA_LIB_KRB5 and
+dnl RRA_LIB_KRB5_OPTIONAL. The single argument, if "true", says to fail if
+dnl Kerberos could not be found. Set up rra_krb5_incroot for later header
+dnl checking.
+AC_DEFUN([_RRA_LIB_KRB5_INTERNAL],
+[AC_REQUIRE([RRA_ENABLE_REDUCED_DEPENDS])
+ rra_krb5_incroot=
+ AS_IF([test x"$rra_krb5_includedir" != x],
+ [rra_krb5_incroot="$rra_krb5_includedir"],
+ [AS_IF([test x"$rra_krb5_root" != x],
+ [rra_krb5_incroot="${rra_krb5_root}/include"])])
+ AS_IF([test x"$rra_reduced_depends" = xtrue],
+ [_RRA_LIB_KRB5_PATHS
+ _RRA_LIB_KRB5_REDUCED([$1])],
+ [AS_IF([test x"$rra_krb5_includedir" = x && test x"$rra_krb5_libdir" = x],
+ [_RRA_LIB_KRB5_CONFIG([$1])],
+ [_RRA_LIB_KRB5_PATHS
+ _RRA_LIB_KRB5_MANUAL([$1])])])
+ rra_krb5_uses_com_err=false
+ AS_CASE([$LIBS], [*-lcom_err*], [rra_krb5_uses_com_err=true])
+ AM_CONDITIONAL([KRB5_USES_COM_ERR], [test x"$rra_krb5_uses_com_err" = xtrue])])
+
+dnl The main macro for packages with mandatory Kerberos support.
+AC_DEFUN([RRA_LIB_KRB5],
+[rra_krb5_root=
+ rra_krb5_libdir=
+ rra_krb5_includedir=
+ rra_use_kerberos=true
+ AC_SUBST([KRB5_CPPFLAGS])
+ AC_SUBST([KRB5_LDFLAGS])
+ AC_SUBST([KRB5_LIBS])
+
+ AC_ARG_WITH([krb5],
+ [AS_HELP_STRING([--with-krb5=DIR],
+ [Location of Kerberos headers and libraries])],
+ [AS_IF([test x"$withval" != xyes && test x"$withval" != xno],
+ [rra_krb5_root="$withval"])])
+ AC_ARG_WITH([krb5-include],
+ [AS_HELP_STRING([--with-krb5-include=DIR],
+ [Location of Kerberos headers])],
+ [AS_IF([test x"$withval" != xyes && test x"$withval" != xno],
+ [rra_krb5_includedir="$withval"])])
+ AC_ARG_WITH([krb5-lib],
+ [AS_HELP_STRING([--with-krb5-lib=DIR],
+ [Location of Kerberos libraries])],
+ [AS_IF([test x"$withval" != xyes && test x"$withval" != xno],
+ [rra_krb5_libdir="$withval"])])
+ _RRA_LIB_KRB5_INTERNAL([true])
+ AC_DEFINE([HAVE_KERBEROS], 1, [Define to enable Kerberos features.])])
+
+dnl The main macro for packages with optional Kerberos support.
+AC_DEFUN([RRA_LIB_KRB5_OPTIONAL],
+[rra_krb5_root=
+ rra_krb5_libdir=
+ rra_krb5_includedir=
+ rra_use_kerberos=
+ AC_SUBST([KRB5_CPPFLAGS])
+ AC_SUBST([KRB5_LDFLAGS])
+ AC_SUBST([KRB5_LIBS])
+
+ AC_ARG_WITH([krb5],
+ [AS_HELP_STRING([--with-krb5@<:@=DIR@:>@],
+ [Location of Kerberos headers and libraries])],
+ [AS_IF([test x"$withval" = xno],
+ [rra_use_kerberos=false],
+ [AS_IF([test x"$withval" != xyes], [rra_krb5_root="$withval"])
+ rra_use_kerberos=true])])
+ AC_ARG_WITH([krb5-include],
+ [AS_HELP_STRING([--with-krb5-include=DIR],
+ [Location of Kerberos headers])],
+ [AS_IF([test x"$withval" != xyes && test x"$withval" != xno],
+ [rra_krb5_includedir="$withval"])])
+ AC_ARG_WITH([krb5-lib],
+ [AS_HELP_STRING([--with-krb5-lib=DIR],
+ [Location of Kerberos libraries])],
+ [AS_IF([test x"$withval" != xyes && test x"$withval" != xno],
+ [rra_krb5_libdir="$withval"])])
+
+ AS_IF([test x"$rra_use_kerberos" != xfalse],
+ [AS_IF([test x"$rra_use_kerberos" = xtrue],
+ [_RRA_LIB_KRB5_INTERNAL([true])],
+ [_RRA_LIB_KRB5_INTERNAL([false])])],
+ [AM_CONDITIONAL([KRB5_USES_COM_ERR], [false])])
+ AS_IF([test x"$KRB5_LIBS" != x],
+ [AC_DEFINE([HAVE_KERBEROS], 1, [Define to enable Kerberos features.])])])
+
+dnl Source used by RRA_FUNC_KRB5_GET_INIT_CREDS_OPT_FREE_ARGS.
+AC_DEFUN([_RRA_FUNC_KRB5_OPT_FREE_ARGS_SOURCE], [RRA_INCLUDES_KRB5] [[
+int
+main(void)
+{
+ krb5_get_init_creds_opt *opts;
+ krb5_context c;
+ krb5_get_init_creds_opt_free(c, opts);
+}
+]])
+
+dnl Check whether krb5_get_init_creds_opt_free takes one argument or two.
+dnl Early Heimdal used to take a single argument. Defines
+dnl HAVE_KRB5_GET_INIT_CREDS_OPT_FREE_2_ARGS if it takes two arguments.
+dnl
+dnl Should be called with RRA_LIB_KRB5_SWITCH active.
+AC_DEFUN([RRA_FUNC_KRB5_GET_INIT_CREDS_OPT_FREE_ARGS],
+[AC_CACHE_CHECK([if krb5_get_init_creds_opt_free takes two arguments],
+ [rra_cv_func_krb5_get_init_creds_opt_free_args],
+ [AC_COMPILE_IFELSE([AC_LANG_SOURCE([_RRA_FUNC_KRB5_OPT_FREE_ARGS_SOURCE])],
+ [rra_cv_func_krb5_get_init_creds_opt_free_args=yes],
+ [rra_cv_func_krb5_get_init_creds_opt_free_args=no])])
+ AS_IF([test $rra_cv_func_krb5_get_init_creds_opt_free_args = yes],
+ [AC_DEFINE([HAVE_KRB5_GET_INIT_CREDS_OPT_FREE_2_ARGS], 1,
+ [Define if krb5_get_init_creds_opt_free takes two arguments.])])])
Added: trunk/debathena/debathena/aclocal/aclocal/lib-depends.m4
===================================================================
--- trunk/debathena/debathena/aclocal/aclocal/lib-depends.m4 (rev 0)
+++ trunk/debathena/debathena/aclocal/aclocal/lib-depends.m4 2013-06-02 04:23:37 UTC (rev 26029)
@@ -0,0 +1,28 @@
+dnl Provides option to change library probes.
+dnl
+dnl This file provides RRA_ENABLE_REDUCED_DEPENDS, which adds the configure
+dnl option --enable-reduced-depends to request that library probes assume
+dnl shared libraries are in use and dependencies of libraries should not be
+dnl probed. If this option is given, the shell variable rra_reduced_depends
+dnl is set to true; otherwise, it is set to false.
+dnl
+dnl This macro doesn't do much but is defined separately so that other macros
+dnl can require it with AC_REQUIRE.
+dnl
+dnl The canonical version of this file is maintained in the rra-c-util
+dnl package, available at <http://www.eyrie.org/~eagle/software/rra-c-util/>.
+dnl
+dnl Written by Russ Allbery <rra@stanford.edu>
+dnl Copyright 2005, 2006, 2007
+dnl The Board of Trustees of the Leland Stanford Junior University
+dnl
+dnl This file is free software; the authors give unlimited permission to copy
+dnl and/or distribute it, with or without modifications, as long as this
+dnl notice is preserved.
+
+AC_DEFUN([RRA_ENABLE_REDUCED_DEPENDS],
+[rra_reduced_depends=false
+AC_ARG_ENABLE([reduced-depends],
+ [AS_HELP_STRING([--enable-reduced-depends],
+ [Try to minimize shared library dependencies])],
+ [AS_IF([test x"$enableval" = xyes], [rra_reduced_depends=true])])])
Added: trunk/debathena/debathena/aclocal/aclocal/lib-pathname.m4
===================================================================
--- trunk/debathena/debathena/aclocal/aclocal/lib-pathname.m4 (rev 0)
+++ trunk/debathena/debathena/aclocal/aclocal/lib-pathname.m4 2013-06-02 04:23:37 UTC (rev 26029)
@@ -0,0 +1,61 @@
+dnl Determine the library path name.
+dnl
+dnl Red Hat systems and some other Linux systems use lib64 and lib32 rather
+dnl than just lib in some circumstances. This file provides an Autoconf
+dnl macro, RRA_SET_LDFLAGS, which given a variable, a prefix, and an optional
+dnl suffix, adds -Lprefix/lib, -Lprefix/lib32, or -Lprefix/lib64 to the
+dnl variable depending on which directories exist and the size of a long in
+dnl the compilation environment. If a suffix is given, a slash and that
+dnl suffix will be appended, to allow for adding a subdirectory of the library
+dnl directory.
+dnl
+dnl This file also provides the Autoconf macro RRA_SET_LIBDIR, which sets the
+dnl libdir variable to PREFIX/lib{,32,64} as appropriate.
+dnl
+dnl The canonical version of this file is maintained in the rra-c-util
+dnl package, available at <http://www.eyrie.org/~eagle/software/rra-c-util/>.
+dnl
+dnl Written by Russ Allbery <rra@stanford.edu>
+dnl Copyright 2008, 2009
+dnl The Board of Trustees of the Leland Stanford Junior University
+dnl
+dnl This file is free software; the authors give unlimited permission to copy
+dnl and/or distribute it, with or without modifications, as long as this
+dnl notice is preserved.
+
+dnl Probe for the alternate library name that we should attempt on this
+dnl architecture, given the size of an int, and set rra_lib_arch_name to that
+dnl name. Separated out so that it can be AC_REQUIRE'd and not run multiple
+dnl times.
+dnl
+dnl There is an unfortunate abstraction violation here where we assume we know
+dnl the cache variable name used by Autoconf. Unfortunately, Autoconf doesn't
+dnl provide any other way of getting at that information in shell that I can
+dnl see.
+AC_DEFUN([_RRA_LIB_ARCH_NAME],
+[rra_lib_arch_name=lib
+ AC_CHECK_SIZEOF([long])
+ AS_IF([test "$ac_cv_sizeof_long" -eq 4 && test -d /usr/lib32],
+ [rra_lib_arch_name=lib32],
+ [AS_IF([test "$ac_cv_sizeof_long" -eq 8 && test -d /usr/lib64],
+ [rra_lib_arch_name=lib64])])])
+
+dnl Set VARIABLE to -LPREFIX/lib{,32,64} or -LPREFIX/lib{,32,64}/SUFFIX as
+dnl appropriate.
+AC_DEFUN([RRA_SET_LDFLAGS],
+[AC_REQUIRE([_RRA_LIB_ARCH_NAME])
+ AS_IF([test -d "$2/$rra_lib_arch_name"],
+ [AS_IF([test x"$3" = x],
+ [$1="[$]$1 -L$2/${rra_lib_arch_name}"],
+ [$1="[$]$1 -L$2/${rra_lib_arch_name}/$3"])],
+ [AS_IF([test x"$3" = x],
+ [$1="[$]$1 -L$2/lib"],
+ [$1="[$]$1 -L$2/lib/$3"])])
+ $1=`echo "[$]$1" | sed -e 's/^ *//'`])
+
+dnl Set libdir to PREFIX/lib{,32,64} as appropriate.
+AC_DEFUN([RRA_SET_LIBDIR],
+[AC_REQUIRE([_RRA_LIB_ARCH_NAME])
+ AS_IF([test -d "$1/$rra_lib_arch_name"],
+ [libdir="$1/${rra_lib_arch_name}"],
+ [libdir="$1/lib"])])
Modified: trunk/debathena/debathena/aclocal/debian/changelog
===================================================================
--- trunk/debathena/debathena/aclocal/debian/changelog 2013-05-31 21:38:30 UTC (rev 26028)
+++ trunk/debathena/debathena/aclocal/debian/changelog 2013-06-02 04:23:37 UTC (rev 26029)
@@ -1,9 +1,15 @@
debathena-aclocal (1.1.3) UNRELEASED; urgency=low
+ [ Jonathan Reed ]
* Switch from control.in to control (Trac: #561)
* Bump Standards-Version to 3.9.3
* Bump compat level to 7
+ [ Alexander Chernyakhovsky ]
+ * Convert to dh7
+ * Include Russ Allbery's excellent AFS and KRB5 detection macros in
+ preparation to transition away from the old-style Athena macros.
+
-- Jonathan Reed <jdreed@mit.edu> Wed, 03 Apr 2013 13:30:48 -0400
debathena-aclocal (1.1.2) unstable; urgency=low
Modified: trunk/debathena/debathena/aclocal/debian/control
===================================================================
--- trunk/debathena/debathena/aclocal/debian/control 2013-05-31 21:38:30 UTC (rev 26028)
+++ trunk/debathena/debathena/aclocal/debian/control 2013-06-02 04:23:37 UTC (rev 26029)
@@ -2,7 +2,7 @@
Section: debathena/devel
Priority: extra
Maintainer: Debathena Project <debathena@mit.edu>
-Build-Depends: cdbs, debhelper, dh-buildinfo
+Build-Depends: debhelper (>= 7)
Standards-Version: 3.9.3
Package: debathena-aclocal
Modified: trunk/debathena/debathena/aclocal/debian/debathena-aclocal.install
===================================================================
--- trunk/debathena/debathena/aclocal/debian/debathena-aclocal.install 2013-05-31 21:38:30 UTC (rev 26028)
+++ trunk/debathena/debathena/aclocal/debian/debathena-aclocal.install 2013-06-02 04:23:37 UTC (rev 26029)
@@ -1,2 +1 @@
-
aclocal/* usr/share/aclocal
Modified: trunk/debathena/debathena/aclocal/debian/rules
===================================================================
--- trunk/debathena/debathena/aclocal/debian/rules 2013-05-31 21:38:30 UTC (rev 26028)
+++ trunk/debathena/debathena/aclocal/debian/rules 2013-06-02 04:23:37 UTC (rev 26029)
@@ -1,3 +1,3 @@
#!/usr/bin/make -f
-
-include /usr/share/cdbs/1/rules/debhelper.mk
+%:
+ dh $@
