[1011] in Kerberos-V5-bugs
configuration changes --- common tests...
daemon@ATHENA.MIT.EDU (epeisach@MIT.EDU)
Wed Dec 28 13:18:30 1994
From: epeisach@MIT.EDU
Date: Wed, 28 Dec 1994 13:18:21 -0500
To: krb5-bugs@MIT.EDU
Cc: probe@MIT.EDU
aclocal.m4:
Add KRB5_SETPGRP_TWOARG and KRB5_GETPGRP_ONEARG
appl/bsd/configure.in:
setenv - the test should be rewritten. (the original idea was to
test if setenv took two arguments - but that is not what
is being tested unless setenv is a builtin into the
compiler). This allows for caching...
Use KRB5_SETPGRP_TWOARG and KRB5_GETPGRP_ONEARG instead of tests
appl/telnet/telnetd/configure.in:
Use KRB5_SETPGRP_TWOARG (this test - with caching is moved to
aclocal.m4)
===================================================================
RCS file: /mit/krb5/.cvsroot/src/aclocal.m4,v
retrieving revision 1.40
diff -c -r1.40 aclocal.m4
*** 1.40 1994/12/27 11:12:30
--- aclocal.m4 1994/12/28 16:47:54
***************
*** 617,619 ****
--- 617,651 ----
AC_DEFINE(POSIX_FILE_LOCKS)
fi
])])dnl
+ dnl
+ dnl
+ dnl Check if setpgrp takes two arguments
+ dnl
+ dnl KRB5_SETPGRP_TWOARG
+ AC_DEFUN([KRB5_SETPGRP_TWOARG],dnl
+ [AC_MSG_CHECKING([if setpgrp takes two arguments])
+ AC_CACHE_VAL(krb5_cv_sys_setpgrp_two,
+ [AC_TRY_LINK(
+ [#include <unistd.h>],[setpgrp(0,0)],
+ krb5_cv_sys_setpgrp_two=yes,krb5_cv_sys_setpgrp_two=no)])
+ AC_MSG_RESULT($krb5_cv_sys_setpgrp_two)
+ if test $krb5_cv_sys_setpgrp_two = yes; then
+ AC_DEFINE(SETPGRP_TWOARG)
+ fi
+ ])dnl
+ dnl
+ dnl
+ dnl Check if getpgrp takes one argument
+ dnl
+ dnl KRB5_GETPGRP_ONEARG
+ AC_DEFUN([KRB5_GETPGRP_ONEARG],dnl
+ [AC_MSG_CHECKING([arguments of getpgrp])
+ AC_CACHE_VAL(krb5_cv_sys_getpgrp_one,
+ [AC_TRY_LINK(
+ [#include <unistd.h>],[int pid = getpgrp()],
+ krb5_cv_sys_getpgrp_one=void,krb5_cv_sys_getpgrp_one=pid)])
+ AC_MSG_RESULT($krb5_cv_sys_getpgrp_one)
+ if test $krb5_cv_sys_getpgrp_one = void; then
+ AC_DEFINE(GETGRP_ONEARG)dnl Yes, this is backwards, but is how used
+ fi
+ ])dnl
===================================================================
RCS file: /mit/krb5/.cvsroot/src/appl/bsd/configure.in,v
retrieving revision 5.34
diff -c -r5.34 configure.in
*** 5.34 1994/12/27 19:48:34
--- configure.in 1994/12/28 16:38:59
***************
*** 83,113 ****
AC_MSG_RESULT(no))
dnl
dnl
! AC_MSG_CHECKING([setenv])
! AC_TRY_COMPILE(
! [setenv();],[setenv("PATH","/bin",0)],
! AC_MSG_RESULT(yes),
! [AC_MSG_RESULT(no)
! SETENVSRC=setenv.c
SETENVOBJ=setenv.o
AC_SUBST([SETENVSRC])
AC_SUBST([SETENVOBJ])])
dnl
dnl
! AC_MSG_CHECKING([arguments to getpgrp])
! AC_TRY_COMPILE(
! [#include <unistd.h>], [int pid = getpgrp()],
! [AC_MSG_RESULT(void)
! AC_DEFINE(GETGRP_ONEARG)],
! AC_MSG_RESULT(pid))
! dnl
! dnl
! AC_MSG_CHECKING([number of arguments to setpgrp])
! AC_TRY_COMPILE(
! [#include <unistd.h>],[setpgrp(0,0)],
! [AC_MSG_RESULT(two)
! AC_DEFINE(SETPGRP_TWOARG)],
! AC_MSG_RESULT(void))
dnl
dnl
ADD_DEF(-DKERBEROS)
--- 83,97 ----
AC_MSG_RESULT(no))
dnl
dnl
! AC_CHECK_FUNC(setenv,
! ,[SETENVSRC=setenv.c
SETENVOBJ=setenv.o
AC_SUBST([SETENVSRC])
AC_SUBST([SETENVOBJ])])
dnl
dnl
! KRB5_GETPGRP_ONEARG
! KRB5_SETPGRP_TWOARG
dnl
dnl
ADD_DEF(-DKERBEROS)
===================================================================
RCS file: /mit/krb5/.cvsroot/src/appl/telnet/telnetd/configure.in,v
retrieving revision 5.13
diff -c -r5.13 configure.in
*** 5.13 1994/11/18 19:18:07
--- configure.in 1994/12/01 19:07:27
***************
*** 43,56 ****
AC_HEADER_CHECK(sys/stream.h,AC_DEFINE(STREAMS))
AC_HEADER_CHECK(utmpx.h,AC_DEFINE(UTMPX))
AC_FUNC_CHECK(cgetent,AC_DEFINE(HAS_CGETENT))
! AC_MSG_CHECKING([if setpgrp takes two arguments])
! dnl
! AC_CACHE_VAL(krb5_cv_sys_setpgrp_two,
! [AC_TRY_LINK(
! [#include <unistd.h>],[setpgrp(0,0)],
! krb5_cv_sys_setpgrp_two=yes,krb5_cv_sys_setpgrp_two=no)])
! AC_MSG_RESULT($krb5_cv_sys_setpgrp_two)
! if test $krb5_cv_sys_setpgrp_two = yes; then
! AC_DEFINE(SETPGRP_TWOARG)
! fi
V5_AC_OUTPUT_MAKEFILE
--- 43,47 ----
AC_HEADER_CHECK(sys/stream.h,AC_DEFINE(STREAMS))
AC_HEADER_CHECK(utmpx.h,AC_DEFINE(UTMPX))
AC_FUNC_CHECK(cgetent,AC_DEFINE(HAS_CGETENT))
! KRB5_SETPGRP_TWOARG
V5_AC_OUTPUT_MAKEFILE
